package {
	import alternativa.engine3d.materials.SpriteTextureMaterial;

	import alternativa.engine3d.primitives.Cone;
	import alternativa.engine3d.core.Sprite3D;
	import alternativa.engine3d.core.Object3D;
	import alternativa.types.Point3D;
	import alternativa.types.Texture;
	import alternativa.utils.*

	import flash.display.Sprite;
	import flash.display.BlendMode;
	import flash.display.BitmapData;
	import flash.display.Bitmap;
	import flash.display.GradientType;

	import flash.filters.BlurFilter; 
	import flash.filters.BitmapFilterQuality; 	
	import flash.geom.Matrix;


	[SWF(width = 465, height = 465, frameRate = 24,backgroundColor=0x000000)]
	/**
	 * Alternativa3D を簡単に扱うためのベーシックテンプレート
	 * @author Yasu (clockmaker)
	 */
	public class SimpleDemo extends Sprite {

		
		public function SimpleDemo():void {
			// テンプレートを作成します
			var template:BasicTemplate = new BasicTemplate();
			addChild(template);
			template.camera.coords = new Point3D(200,-500,200);


			// お絵かき用Sprite
			var tempSprite:Sprite=new Sprite();

			//球用のグラデーションを書く
			var colors:Array=new Array(0xCCCCCC,0x000000,0x333333)
			var alphas:Array=new Array(1,1,1)
			var ratios:Array=new Array(0,200,255)
			var matrix:Matrix=new Matrix()

			matrix.createGradientBox(160,160,0,-50,-50)
			tempSprite.graphics.beginGradientFill(GradientType.RADIAL,colors, alphas, ratios, matrix)
			tempSprite.graphics.drawCircle(50,50,50)

			var bmdBall:BitmapData=new BitmapData(100,100,true,0x00FF0000)
			bmdBall.draw(tempSprite)

			var cmtBall:SpriteTextureMaterial=new SpriteTextureMaterial(new Texture(bmdBall),1,true)

			// Sprite3D（球）を作成します
			var ball:Sprite3D=new Sprite3D()
			ball.material=cmtBall;
			template.scene.root.addChild(ball);



			//光を描く
			tempSprite.graphics.clear()
			tempSprite.graphics.beginFill(0xFFFF00,1) 
			tempSprite.graphics.drawCircle(0,0,20) 
			tempSprite.graphics.beginFill(0xFFFFFFF,1) 
			tempSprite.graphics.drawCircle(0,0,10) 

			var filter:BlurFilter = new BlurFilter(10, 10, BitmapFilterQuality.HIGH); 
			var myFilters:Array = [filter] 
			tempSprite.filters = myFilters; 

			var mtr:Matrix=new Matrix(); 
			mtr.translate(tempSprite.width, tempSprite.height) 

			var bmdLight:BitmapData=new BitmapData(100,100,true,0x00FF0000)
			bmdLight.draw(tempSprite,mtr)

			var cmtLight:SpriteTextureMaterial=new SpriteTextureMaterial(new Texture(bmdLight),1,true)

			// Sprite3D（円）作成します
			var light:Sprite3D=new Sprite3D()
			light.material=cmtLight;
			template.scene.root.addChild(light);






			var v:Number
			var r:Number

			var angle=0

			template.onPreRender = function():void {

				// 立方体を回転させます (角度はラジアン)
				angle++
				// 球を移動 (角度はラジアン)
				ball.x=Math.sin(angle * Math.PI / 180*4)*200
				light.z=Math.cos(angle * Math.PI / 180*4)*200
				light.y=Math.sin(angle * Math.PI / 180*4)*200


				// マウスがステージの高さ何%の位置にあるか算出
				//var rateY:Number = mouseY / stage.stageHeight;
				
				// カメラの高さの座標を調整
				// イージングの公式 対象の値 += (目標値 - 現在の値) * 減速率
				//template.camera.y += ( - 1000 * rateY - template.camera.y) * 0.1;
				
				// カメラの座標を中央に向かせる
				template.cameraContoller.lookAt(new Point3D());
			}
		}


	}
}






import alternativa.engine3d.controllers.CameraController;
import alternativa.engine3d.core.Camera3D;
import alternativa.engine3d.core.Object3D;
import alternativa.engine3d.core.Scene3D;
import alternativa.engine3d.display.View;
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageQuality;
import flash.display.StageScaleMode;
import flash.events.Event;


/**
 * BasicTemplate for Alternativa3D
 * Alternativa3Dを扱いやすくするためのテンプレートです
 * @author Yasu
 */
class BasicTemplate extends Sprite{
	/**
	 * シーンインスタンスです。
	 */
	public var scene:Scene3D;
	/**
	 * ビューインスタンスです。
	 */
	public var view:View;
	/**
	 * カメラインスタンスです。
	 */
	public var camera:Camera3D;
	/**
	 * カメラコントローラーです。
	 */
	public var cameraContoller:CameraController;
	
	private var _viewWidth:int;
	private var _viewHeight:int;
	private var _scaleToStage:Boolean;

	/**
	 * 新しい BasicTemplate インスタンスを作成します。
	 * @param	viewWidth
	 * @param	viewHeight
	 * @param	scaleToStage
	 */
	public function BasicTemplate(viewWidth:int=640, viewHeight:int=480, scaleToStage:Boolean = true) {
		_viewWidth = viewWidth;
		_viewHeight = viewHeight;
		_scaleToStage = scaleToStage;
		
		// Creating scene
		scene = new Scene3D();
		scene.splitAnalysis = false; // not analysis for performance
		scene.root = new Object3D();
		
		// Adding camera
		camera = new Camera3D();
		camera.z = -1000;
		scene.root.addChild(camera);
		
		// camera contoller
		cameraContoller = new CameraController(this);
		cameraContoller.camera = camera;
		
		// set view
		view = new View();
		view.camera = camera;
		addChild(view);
		
		// stage
		if (stage) init();
		else addEventListener(Event.ADDED_TO_STAGE, init);
	}
	
	/**
	 * 初期化されたときに実行されるイベントです。
	 * 初期化時に実行したい処理をオーバーライドして記述します。
	 */
	protected function atInit():void {}
	
	/**
	 * 初期化されたときに実行されるイベントです。
	 * 初期化時に実行したい処理を記述します。
	 */
	private var _onInit:Function = function():void { };
	public function get onInit():Function { return _onInit; }
	public function set onInit(value:Function):void {
		_onInit = value;
	}
	
	/**
	 * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
	 * レンダリング前に実行したい処理をオーバーライドして記述します。
	 */
	protected function atPreRender():void {}
	
	/**
	 * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
	 * レンダリング前に実行したい処理を記述します。
	 */
	private var _onPreRender:Function = function():void{};
	public function get onPreRender():Function { return _onPreRender; }
	public function set onPreRender(value:Function):void {
		_onPreRender = value;
	}
	
	/**
	 * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
	 * レンダリング後に実行したい処理をオーバーライドして記述します。
	 */
	protected function atPostRender():void {
	}
	
	/**
	 * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
	 * レンダリング後に実行したい処理を記述します。
	 */
	protected var _onPostRender:Function = function():void{};
	public function get onPostRender():Function { return _onPostRender; }
	public function set onPostRender(value:Function):void {
		_onPostRender = value;
	}
	
	/**
	 * レンダリングを開始します。
	 */
	public function startRendering():void {
		addEventListener(Event.ENTER_FRAME, onRenderTick);
	}
	/**
	 * レンダリングを停止します。
	 */
	public function stopRendering():void {
		removeEventListener(Event.ENTER_FRAME, onRenderTick);
	}
	
	/**
	 * シングルレンダリング(レンダリングを一回だけ)を実行します。
	 */
	public function singleRender():void {
		onRenderTick();
	}
	
	/**
	 * @private
	 */
	private function init(e:Event = null):void {
		stage.scaleMode = StageScaleMode.NO_SCALE;
		stage.align = StageAlign.TOP_LEFT;
		stage.quality = StageQuality.HIGH;

		// resize
		stage.addEventListener(Event.RESIZE, onResize);
		onResize(null);
		
		// render
		startRendering();
		
		atInit();
		_onInit();
		
	}
	
	/**
	 * @private
	 */
	private function onRenderTick(e:Event = null):void {
		atPostRender();
		_onPostRender();
		scene.calculate();
		atPreRender();
		_onPreRender();
	}
	
	/**
	 * @private
	 */
	private function onResize(event:Event = null):void {
		if (_scaleToStage) {
			view.width = stage.stageWidth;
			view.height = stage.stageHeight;
		}else {
			view.width = _viewWidth;
			view.height = _viewHeight;
		}
	}
}